Google Chrome'u Taşınabilir Yapmak | bildirgec.org

google chrome hızı ve kullanım basitliği ile gönüllerimizde taht kurmuş bir tarayıcı.

2. kurulum sonrasındaki dialog penceresini kapatın.

3. başlat menüsündeki ya da masaüstündeki google chrome kısayolunu sağ tıklayıp özellikleri tıklayın. sonrasında hedef bul'u tıklayın.

4. karşınıza açılan pencereden bir üst dizine çıkın. karşınıza gelecek "Application" ve "User Data" klasörlerini seçip birinin üzerinde sağ tuş tıklayıp kopyalayı tıklayın (ya da CTRL C)

istediğiniz bir yere (mesela flash belleğiniz) istediğiniz bir adda yeni klasör yaratıp içine girdikten sonra sağ tuş yapıştır yapın (ya da ctrl v)

5. "user data" klasörünü "application" klasörünün içine sürükle bırak yapın.

6. sonrasında "application" klasörüne girin, numerik isimli klasör (bende 2.0.172.43) dışındaki klasör içindeki tüm dosyaları seçip numerik isimli klasörün içine sürükle bırak yapın.

7. numerik isimli klasörün ismini isteğinize göre değiştirin (mesela taşınabilir chome, chrome v.b.)

8. "application" klasörüne girin, chrome.exe dosyasının üzerinde sağ tuş tıklayıp kısayol yarat'ı tıklayın. sonrasında kısayol üzerinde sağ tuş ve özellikleri tıklayın.
hedef kutucuğunda satırın sonuna; --user-data-dir="User Data"
yı ekleyin. yani hedef;
x:\xxx\chrome.exe --user-data-dir="User Data"
şeklinde olmalı.
kısayolun ismini istediğiniz şekilde değiştirdikten sonra chrome taşınabilir olarak çalışabilecektir.

başlat sonrasında çalıştır'ı tıklayın, notepad yazıp tamam'ı tıklayın. sonrada alttaki yazıları notepad'e kopyala, yapıştır yapın.

@echo off

if exist "%HOMEDRIVE%\tasinabilir programlar\Chrome" goto hata0

:basla
if exist "%temp%\chrome_versiyon.x" del "%temp%\chrome_versiyon.x"

if not exist "%HOMEDRIVE%%HOMEPATH%\Local Settings\Application Data\Google\Chrome\Application" goto hata1

dir /b /a:d "%HOMEDRIVE%%HOMEPATH%\Local Settings\Application Data\Google\Chrome\Application" >"%temp%\chrome_versiyon.x"

if not exist "%temp%\chrome_versiyon.x" goto hata2

for /f %%a in (%temp%\chrome_versiyon.x) do (
set versiyon=%%a
goto kontrol
)

:kontrol
if not exist "%HOMEDRIVE%%HOMEPATH%\Local Settings\Application Data\Google\Chrome\Application\%versiyon%" goto hata1

:kopyala
md "%HOMEDRIVE%\tasinabilir programlar"
xcopy /E /Q "%HOMEDRIVE%%HOMEPATH%\Local Settings\Application Data\Google\Chrome" "%HOMEDRIVE%\tasinabilir programlar\"
move /Y "%HOMEDRIVE%\tasinabilir programlar\User Data" "%HOMEDRIVE%\tasinabilir programlar\Application\%versiyon%"
move /Y "%HOMEDRIVE%\tasinabilir programlar\Application\Dictionaries" "%HOMEDRIVE%\tasinabilir programlar\Application\%versiyon%"
move /Y "%HOMEDRIVE%\tasinabilir programlar\Application\chrome.exe" "%HOMEDRIVE%\tasinabilir programlar\Application\%versiyon%\"
move /Y "%HOMEDRIVE%\tasinabilir programlar\Application\%versiyon%" "%HOMEDRIVE%\tasinabilir programlar\"
echo x >"%HOMEDRIVE%\tasinabilir programlar\%versiyon%\First Run"
ren "%HOMEDRIVE%\tasinabilir programlar\%versiyon%" "Chrome"
rd /s /q "%HOMEDRIVE%\tasinabilir programlar\Chrome\Installer"
rd /s /q "%HOMEDRIVE%\tasinabilir programlar\Application"
echo start chrome.exe --user-data-dir="User Data" > "%HOMEDRIVE%\tasinabilir programlar\Chrome\Tasinabilir Chrome Calistir.bat"
echo Tasinabilir Yapilan Versiyon: %versiyon% > "%HOMEDRIVE%\tasinabilir programlar\Chrome\Versiyon.txt"
explorer.exe "%HOMEDRIVE%\tasinabilir programlar\Chrome"

exit

:hata0
echo.
echo.
echo D I K K A T ! ! !
echo.
echo DAHA ONCE TASINABILIR YAPILMIS CHROME DOSYALARI BULUNDU ...
echo.
echo BUNLARIN SILINMESINI ISTIYORSANIZ HERHANGI BIR TUSA BASIN.
echo.
echo ISTEMIYORSANIZ BU UYGULAMADAN CIKIN VE DOSYALARINIZI BASKA
echo.
echo BIR YERE YEDEKLEYIN ...
echo.
echo.
pause
rd /s /q "%HOMEDRIVE%\tasinabilir programlar\Chrome"
goto basla

:hata1
echo Google Chrome Bulunamadi ... Kurulu Oldugundan Emin Misin?
echo "http://www.google.com/chrome" adresinden indirebilirsin ...
echo.
pause
exit

:hata2
echo versiyon dosyasi okunamadi yada yazilamadi ...
echo bilgisayar oturumunu yetkili hesabi ile actigina eminmisin?
echo.
pause
exit

(kodun aynısına buradanda erişebilirsiniz)

sonrada dosya > kaydet i tıklayın. dosya ismi yerine chrome.bat (yada bat la biten ne isterseniz) yazın. kayıt türünü "tüm dosyalar" olarak değiştirip tamam ı tıklayın.

bu komut dosyası sizin yerinize "c:\tasinabilir programlar\chrome" klasorü altında google chrome'u taşınabilir bir hale getirecektir.
"Tasinabilir Chrome Calistir.bat" dosyasını tıkladığınızda da google chrome taşınabilir olarak çalışacaktır.